Program to draw the Mandelbrot set

Remember the definition:
The Mandelbrot set is the set M of complex numbers c=x+iy for which the series
{ z₀=0 , z₁=c , ... , z_n+1=(z_n)² + c , ... } is bounded.

The Borland/Turbo Pascal program below shows how this is used to generate those well-known colourful images of fractals!

Take every point (x,y) in a defined rectangle (the display screen);
calculate successive iterations: z₁=x+iy, ..., z_n+1=(z_n)²+z₁, ... until either:

• the magnitude of z_n becomes greater than 2,
• n reaches some (big) number of iterations N (here 16).

program fractal;
uses graph;
var
   grdriver,grmode,xs,ys,iter:integer;
   xc,yc,x,y,x0,mag:single;
begin
   grdriver:=detect;
   initgraph(grdriver,grmode,'bgi');
   for ys:=239 downto 0 do begin
      yc:=ys/160;
      for xs:=0 to 639 do begin
         xc:=xs/160-2.5;
         x:=xc;y:=yc;iter:=0;
         repeat
            x0:=x;
            x:=sqr(x)-sqr(y)+xc;
            y:=2*x0*y+yc;
            mag:=sqr(x)+sqr(y);
            inc(iter)
         until ((mag>4) or (iter=16));
         putpixel(xs,240-ys,iter);
         putpixel(xs,240+ys,iter)
      end
   end;
   readln;closegraph
end.

Note that the program expects to find a graphic-driver (vga.bgi) in the subdirectory 'bgi'.

There are many more sophisticated programs available, the most popular is FRACTINT.
That program does not only allow to generate images of the Mandelbrot set, but all possible types of fractals.